Skip to main content

PK/PD Modeling with NONMEM

2 Sample NONMEM control stream

Here are a few sample NONMEM control stream files (.ctl or .mod)

2.1 One compartment model - Oral 

;;------------------------------------------------------------------------------
;; Name: mymodel.ctl
;;
;; Project brief: sample description
;;
;; Dataset description: sample description
;;
;; Created on Nov 10, 2023 01:28:08 EST by obi obianom for NONMEM 7.5
;;------------------------------------------------------------------------------

$PROBLEM PK model

$INPUT  ;; Change to dataset
  CENSOR AORTA=DROP ID DATE=DROP TIME AMT EVID MDV TAD DV        

$DATA datafile.CSV IGNORE=C 

$SUBROUTINES 
  ADVAN2 TRANS2     ;; data 1-comp with first order absorption

$PK
  TVKA = THETA(3)
  KA = TVKA

  TVCL = THETA(4)
  CL = TVCL*EXP(ETA(1))
  MU_1 = LOG(TVCL)

  TVV  = THETA(5)
  V = TVV * EXP(ETA(2))
  MU_2 = LOG(TVV)

  S2 = V  ;; Scaling compartment (check units of dose and observations)

$THETA      ;; set realistic initial estimates
  (0, 0.5)  ;1 prop
  (0, 0.1)      ;2 add
  (0, 4)        ;3 Ka
  (0, 30)       ;4 CL
  (0, 200)      ;5 V

$OMEGA BLOCK(2)
  0.09              ; IIV-CL
  0.01 0.09         ; IIV-V

$SIGMA
  1 FIX  ;residual variability

$ERROR      ;; Calculation based on linear (non log-transformed) data
  IPRED = F
  IRES = DV-IPRED
  W = IPRED*THETA(1)+THETA(2)
  IF (W.EQ.0) W = 1
  IWRES = IRES/W
  Y= IPRED+W*ERR(1)

$EST METHOD=1 MAXEVAL=99999 SIG=3 PRINT=5 NOABORT POSTHOC INTERACTION   ;; Estimation methode FOCE+interaction

$COV PRINT=E UNCONDITIONAL

$TABLE ID TAD IPRED IWRES CWRES  EVID MDV TIME NOPRINT ONEHEADER FILE=SDTAB001
$TABLE ID CL V KA ETA1 ETA2 NOPRINT ONEHEADER FILE=PATAB001
$TABLE ID NOPRINT ONEHEADER FILE=COTAB001
$TABLE ID NOPRINT ONEHEADER FILE=CATAB001

2.2 One compartment model - IV 

;;------------------------------------------------------------------------------
;; Name: mymodel.ctl
;;
;; Project brief: sample description
;;
;; Dataset description: sample description
;;
;; Created on Nov 10, 2023 01:28:08 EST by obi obianom for NONMEM 7.5
;;------------------------------------------------------------------------------

$PROBLEM PK model

$INPUT  ;; Change to dataset
  CENSOR AORTA=DROP ID DATE=DROP TIME AMT EVID MDV TAD DV        

$DATA datafile.CSV IGNORE=C  

$SUBROUTINES 
  ADVAN1 TRANS2     ;; 1-compartment iv data

$PK
  CL = THETA(3) * EXP(ETA(1))
  V = THETA(4) * EXP(ETA(2))
  
  S1 = V   ;; scaling of compartment check units of dose and observations

$THETA      ;; set realistic initial estimates (also for proportional and additive error)
  (0, 0.1)  ;1 prop
  (0, 0.5)      ;2 add
  (0, 30)       ;3 CL
  (0, 200)      ;4 V

$OMEGA BLOCK(2)
  0.09              ;; IIV-CL
  0.01 0.09         ;; IIV-V

$SIGMA
  1 FIX  ;residual variability

$ERROR      ;; For calculation based on linear (non log-transformed) data
  IPRED = F
  IRES = DV-IPRED
  W = IPRED*THETA(1)+THETA(2)
  IF (W.EQ.0) W = 1
  IWRES = IRES/W
  Y= IPRED+W*ERR(1)

$EST METHOD=1 MAXEVAL=99999 SIG=3 PRINT=5 NOABORT POSTHOC INTERACTION   ;; Estimation method FOCE+interaction

$COV PRINT=E UNCONDITIONAL

$TABLE ID TAD IPRED IWRES CWRES EVID MDV TIME NOPRINT ONEHEADER FILE=SDTAB001
$TABLE ID CL V ETA1 ETA2 NOPRINT ONEHEADER FILE=PATAB001
$TABLE ID NOPRINT ONEHEADER FILE=COTAB001
$TABLE ID NOPRINT ONEHEADER FILE=CATAB001

2.3 Two compartment model - Oral 

;;------------------------------------------------------------------------------
;; Name: mymodel.ctl
;;
;; Project brief: sample description
;;
;; Dataset description: sample description
;;
;; Created on Nov 10, 2023 01:28:08 EST by obi obianom for NONMEM 7.5
;;------------------------------------------------------------------------------

$PROBLEM PK model

$INPUT
  CENSOR AORTA=DROP ID DATE=DROP TIME AMT EVID MDV TAD DV
    
$DATA Dataset.CSV IGNORE=C

$SUBROUTINES 
  ADVAN4 TRANS4     ;; 2-comp with first order absorption

$PK
  TVKA = THETA(3)
  KA = TVKA*EXP(ETA(3))
  MU_3 = LOG(TVKA)

  TVCL = THETA(4)
  CL = TVCL*EXP(ETA(1))
  MU_1 = LOG(TVCL)

  TVV2  = THETA(5)
  V2 = TVV2 * EXP(ETA(2))
  MU_2 = LOG(TVV2)
    
  TVQ = THETA(6)
  Q = TVQ

  TVV3  = THETA(7)
  V3 = TVV3
  
  S2 = V2

$THETA
  (0, 0.5)  ;1 prop
  (0 0.1)   ;2 add
  (0, 4)    ;3 Ka
  (0, 30)       ;4 CL
  (0, 50)       ;5 Vc
  (0, 20)   ;6 Q
  (0, 200)  ;7 Vp
    

$OMEGA BLOCK(3)
  0.09              ; IIV-CL
  0.01 0.09         ; IIV-Vc
  0.01 0.01 0.09    ; IIV-Ka

$SIGMA
 1 FIX  ;residual variability

$ERROR
  IPRED = F
  IRES = DV-IPRED
  W = IPRED*THETA(1)+THETA(2)
  IF (W.EQ.0) W = 1
  IWRES = IRES/W
  Y= IPRED+W*ERR(1)

$EST METHOD=1 MAXEVAL=99999 SIG=3 PRINT=5 NOABORT POSTHOC INTERACTION

$COV PRINT=E UNCONDITIONAL

$TABLE ID TAD IPRED IWRES CWRES EVID MDV TIME NOPRINT ONEHEADER FILE=SDTAB003
$TABLE ID CL V2 Q V3 KA ETA1 ETA2 ETA3 NOPRINT ONEHEADER FILE=PATAB003
$TABLE ID WT NOPRINT ONEHEADER FILE=COTAB003
$TABLE ID NOPRINT ONEHEADER FILE=CATAB003

2.4 Two compartment model - IV 

;;------------------------------------------------------------------------------
;; Name: mymodel.ctl
;;
;; Project brief: sample description
;;
;; Dataset description: sample description
;;
;; Created on Nov 10, 2023 01:28:08 EST by obi obianom for NONMEM 7.5
;;------------------------------------------------------------------------------


$PROBLEM PK model

$INPUT  ;; Pas aan naar dataset
  CENSOR AORTA=DROP ID DATE=DROP TIME AMT EVID MDV TAD DV        

$DATA datafile.CSV IGNORE=C 

$SUBROUTINES 
  ADVAN3 TRANS4         ;; data 2-comp (iv)

$PK                 
  LTVCL = LOG(THETA(3))
  MU_1 = LTVCL          ;; MU_1 referencing 
  CL =  EXP(MU_1 + ETA(1))
  
  LTVV1 = LOG(THETA(4))
  MU_2 = LTVV1
  V1 = EXP(MU_2 + ETA(2))
  
  Q = THETA(5)
  V2 = THETA(6)
  
  S1 = V1

$THETA              ;; set realistic initial estimates
  (0, 0.5)  ;1 prop
  (0, 0.1)  ;2 add
  (0, 30)       ;3 CL
  (0, 200)      ;4 V1
  (0, 30)       ;5 Q
  (0, 200)      ;6 V2

$OMEGA BLOCK(2)
  0.09      ; IIV-CL
  0.01 0.09 ; IIV-V

$SIGMA
  1 FIX  ;residual variability

$ERROR              ;; Based on linear data and proportional and additive error
  IPRED = F
  IRES = DV-IPRED
  W = IPRED*THETA(1)+THETA(2)
  IF (W.EQ.0) W = 1
  IWRES = IRES/W
  Y= IPRED+W*ERR(1)

$EST METHOD=1 MAXEVAL=99999 SIG=3 PRINT=5 NOABORT POSTHOC INTERACTION   ;; Estimation method FOCE+interaction

$COV PRINT=E UNCONDITIONAL

$TABLE ID TAD IPRED IWRES CWRES EVID MDV TIME NOPRINT ONEHEADER FILE=SDTAB001
$TABLE ID CL V1 Q V2 ETA1 ETA2 NOPRINT ONEHEADER FILE=PATAB001
$TABLE ID NOPRINT ONEHEADER FILE=COTAB001
$TABLE ID NOPRINT ONEHEADER FILE=CATAB001

2.5 Three compartment model - Oral 

;;------------------------------------------------------------------------------
;; Name: mymodel.ctl
;;
;; Project brief: sample description
;;
;; Dataset description: sample description
;;
;; Created on Nov 10, 2023 01:28:08 EST by obi obianom for NONMEM 7.5
;;------------------------------------------------------------------------------


$PROBLEM PK model

$INPUT
 CENSOR AORTA=DROP ID DATE=DROP TIME AMT EVID MDV TAD DV

$DATA Dataset.CSV IGNORE=C

$SUBROUTINES 
 ADVAN12 TRANS4         ;; 3-comp with first-order absorption

$PK
  TVKA = THETA(3)
  MU_3 = LOG(TVKA)
  KA = EXP(MU_3+ETA(3))
    
  TVCL = THETA(4)
  MU_1 = LOG(TVCL)
  CL = EXP(MU_1+ETA(1))

  TVV2 = THETA(5)
  MU_2 = LOG(TVV2)
  V2 = EXP(MU_2+ETA(2))

  TVQ3 = THETA(6)
  Q3 = TVQ3

  TVV3  = THETA(7)
  V3 = TVV3
    
  TVQ4 = THETA(8)
  Q4 = TVQ4

  TVV4  = THETA(9)
  V4 = TVV4
  
  SC = V2

$THETA
  (0, 0.5)  ;1 prop
  (0 FIX)   ;2 add
  (0, 4)    ;3 Ka
  (0, 30)       ;4 CL
  (0, 50)       ;5 Vc
  (0, 20)   ;6 Q
  (0, 100)  ;7 Vp
  (0, 10)   ;8 Q4
  (0, 150)  ;9 V4

$OMEGA BLOCK(3)
  0.09              ; IIV-CL
  0.01 0.09         ; IIV-Vc
  0.01 0.01 0.09    ; IIV-Ka

$SIGMA
  1 FIX  ;residual variability 

$ERROR
  IPRED = F
  IRES = DV-IPRED
  W = IPRED*THETA(1)+THETA(2)
  IF (W.EQ.0) W = 1
  IWRES = IRES/W
  Y= IPRED+W*ERR(1)

$EST METHOD=1 MAXEVAL=99999 SIG=3 PRINT=5 NOABORT POSTHOC INTERACTION

$COV PRINT=E UNCONDITIONAL

$TABLE ID TAD IPRED IWRES CWRES EVID MDV TIME NOPRINT ONEHEADER FILE=SDTAB001
$TABLE ID CL V2 Q3 V3 Q4 KA ETA1 ETA2 ETA3 NOPRINT ONEHEADER FILE=PATAB001
$TABLE ID WT NOPRINT ONEHEADER FILE=COTAB001
$TABLE ID NOPRINT ONEHEADER FILE=CATAB001